Wednesday, October 13, 2010

Kae's 4.0 Druid Macros

In an update from my PTR post, I have found that not only have they fixed the OP kitty death pounce of ravagey doom, but also fixed lifebloom for macro useage. Both good things.


MACROS

The following macros are 4.0 updates to the macros I currently use. Healing didn't change much, in terms of spells, so most of these are feral. It is likely I'll be tweaking these macros as I grow accustomed to the new abilities and grow away from my old bind habits. It is also likely that you may find a different arrangement of abilities to be useful: feel free to hack these macros apart and replace things with your own preference. That's what macros are for :)


- NOTE 1: if you are not a primary-spec resto and secondary-spec feral, you will want to look at all instances of [spec:1] and [spec:2] in these macros to replace them with your appropriate spec.

- NOTE 2: I use an old-model G15 keyboard, which offers me at least 4 "easily reachable" extra keybind keys for pinky reach. You might be a little more pressed for keybind space if you don't have or use one of these, and have to rely more on mouse-click actions.

- NOTE 3: Bindpad has a working version here on WoWInterface.



Generic Macro Templates

Cut and paste in your abilities where you'd like. If in doubt, click them out of your spellbook to get the correct name.

Mouseover Heal or Cleanse:

/cast [@mouseover,help] [help] [@player] Spellname


Mouseover or Focus Harm:
(attack your mouseover, or otherwise your focus target, such as with CC)

/cast [@mouseover,harm,nodead] [harm] [@focus,harm,nodead] [@focustarget,harm] [] Spellname


Mouseover or Focus Harm Toggle:
(hold shift to attack or assist your focus target, such as with CC, otherwise mouseover)

/cast [mod:shift,@focus,harm,nodead][mod:shift,@focustarget,harm,nodead][@mouseover,harm,nodead] [harm] [] Spellname


Focus-assist or Target Harm:
(set a main tank as assist, for example)

/cast [@focustarget,harm,nodead] [harm] [] Spellname


Mouseover Help or Target Harm:

/cast [harm] DPSspell; [@mouseover,help] [help] [@player] Healspell


Modifier-toggled casts:

/cast [mod:shift] Spell1; [mod:alt] Spell2; Spell3


Modifier-toggled Helpful Mouseovers:

/cast [mod:shift,@mouseover,help][mod:shift,help][mod:shift,@player] Spell1; [mod:alt][mod:alt,help][mod:alt,@player] Spell2; [@mouseover,help][help][@player] Spell3




Custom Macros

My Skull Bash Key (G12):
Skull bash is our new feral-form spell interrupt. While the following can be done by placing the abilities on your respective stance bars (besides the mouseover portion of Wild Growth), I prefer to just macro it in Bindpad.


#showtooltip
/cast [form:3] Skull Bash(Cat Form); [form:1] Skull Bash(Bear Form)
/stopmacro [spec:2] [form:1/3]
/cast [@mouseover,nodead,exists] [@player] Wild Growth
  • Cat: Skull Bash
  • Bear: Skull Bash
  • Caster [spec:1]: Wild Growth (mouseover)

My Stuns Key (G18):
This key used to be my remove curse macro; my cleanse has been consolidated and thus freed up this button. As above, the following can be done by placing the abilities on your respective stance bars (besides the targeting portion of Cyclone), I prefer to just macro it in Bindpad. You could throw warstomp in there, but I prefer having access to that straight from feral forms.


#showtooltip
/cast [form:3] Maim; [form:1] Bash; [harm][@focus,harm][] Cyclone

  • Cat: Maim
  • Bear: Bash
  • Caster: Cyclone on enemy target, else on enemy focus target, else normal.


Mushroom Toggle:
Casting mushrooms (up to 3 at a time) and detonating them requires different casts. While we won't learn this spell until level 85, it is good to plan ahead and map out where you'd like to put this ability in your binds/bars, and consolidating the two into one toggled macro is a great way to save space.


#showtooltip
/cast [mod:shift] Detonate Mushroom; Wild Mushroom

  • Shift: Detonate Mushrooms (boom them)
  • Normal: Wild Mushroom (place them)

    STAMPEDE (~):
    While we won't learn Stampeding Roar until level 83, I wanted to save a spot for it. While yet again the following can be done by placing the abilities on your respective stance bars, I prefer to just macro it in Bindpad. /shrug


    #showtooltip
    /cast [form:3] Stampeding Roar(Cat Form); [form:1]Stampeding Roar(Bear Form); Hurricane

    • Cat: Stampeding Roar
    • Bear: Stampeding Roar
    • Caster: Hurricane. Because. THUNDER AND LIGHTENING, VERY VERY FRIGHTENING!



    My feral AOE Key (q):
    Swipe gets spammed a lot, as a cat. Swipe has a cooldown as a bear, but it used to get spammed a lot. We'll be getting Thrash, another bear AoE, at 81, so we have to plan for that. I like binding tons of stuff to my q and e keys :)


    #showtooltip
    /cast [mod:shift,form:1] Thrash; [mod:alt,form:1] Mangle(Bear Form); [@mouseover,harm,nodead,form:1][form:1] Swipe(Bear Form); [stealth] Pounce; [mod:shift] Rake; [@mouseover,harm,nodead][] Swipe(Cat Form)
    /startattack [nostealth]

    • Cat:
      • Swipe
      • +shift: Rake
      • +stealth: Pounce
      • If you'd like to add [mod:alt]Mangle(Cat Form); then you'll need to kill the #showtooltip and some blank spaces to make room.

    • Bear:
      • Swipe,
      • +shift: Thrash
      • +alt: Mangle


    My feral "E" Key:
    Pulverize is an important new bear tool you need to include in your rotation. It is a "CP-user" of lacerate stacks, so binding it to your lacerate key makes sense to me. As for cat form, I haven't changed any of my old binds, but will probably replace Maim with something else down the road, once I get used to my new stuns macro.


    #showtooltip
    /cast [mod:shift,form:3] Ferocious Bite; [form:3,mod:alt]Rip; [form:3] Maim
    /stopmacro [form:3]
    /cast [nomod:alt] !Maul
    /cast [mod:shift] Pulverize; Lacerate

    • Cat:
      • Maim (because it's where I'm used to it. If you're using a combined stuns key elsewhere, you may consider replacing this with something else).
      • +shift: Ferocious Bite
      • +alt: Rip (you might consider making this the default by removing the red text, if you don't want Maim here)

    • Bear:
      • Lacerate and Maul,
      • +shift: Pulverize and Maul,
      • +alt: hold alt to not use Maul


    My T Key:
    An update to my "t" key. It's got a bunch of random but useful stuff in it, including my ToL shift. As a note, if you are feral, you might want to consider a cast-sequence instead for catform which is in the next macro down, as you can now use unstealthed Ravage after using feral charge.


    #showtooltip
    /cast [form:1,btn:2][form:1,mod]Enrage
    /cast [form:1,btn:1][mod,form:1]Frenzied Regeneration
    /stopmacro [form:1]
    /cast [mod,form:3]Savage Roar;[form:3]Feral Charge(Cat Form);[mod,spec:1] !Tree of Life; [@mouseover,help][@player]Nourish

    • Bear:
      • Frenzied Regeneration
      • Right click: Enrage
      • +Shift: both Enrage and Frenzied Regen, together
    • Cat:
      • Feral Charge
      • +shift: Savage Roar
    • Caster:
      • Nourish
      • +shift: [spec:1] ToL


    My Catform Charge+Ravage Key (t):
    The improved feral charge talent makes your next ravage usable while not stealthed, for a short period of time after charging in cat form. Note that if your ravage misses or is a failed attempt due to positioning, it still consumes the buff.


    #showtooltip
    /cast [mod] Savage Roar
    /castsequence reset=8 Feral Charge(Cat Form), Ravage

    • Feral Charge and then Ravage (two presses);
    • +shift: Savage Roar

    11 comments:

    Forreststump said...

    With the loss of tree form, I no longer have the handy:

    #showtooltip
    /cast !Tree of Life

    ...single-click power-shifting snare break macro. Any thoughts on a substitute, or are we stuck clicking twice to shift to (example) kitty and back?

    Kae said...

    Hmmm good point. You could try something like:

    /cast [form:3,@mouseover,help] [form:3,@player][form:3] Rejuvenation; Cat Form

    ...as your catform shapeshift, which would allow you to use a rejuvenation cast to break cat form automatically, and not loose mouseover capabilities. That's assuming your catform binds/bars don't already have heals still bound to them. Any heal cast while in a feral form will automatically deshift you back to caster form, iirc.

    Unknown said...

    Have you been able to make the Skull Bash macro work? I tried last night and no matter the form I was in, it kept showing the Skull Bash (requires Cat Form) spell and never let me see the Bear Form one. My old macro on which its based had the Mangle (Cat Form); Mangle (Bear Form) part to it and that wouldn't work so I took out the Cat/Bear Form part since its no longer reflected in the actual name. Anyway, hope I can figure it out tonight, and thanks for all the other macros!

    Kae said...

    Off the top of my head, I know that the actual spell name in the macro cannot have a space between the spell and the parenthesis. For example,

    /cast Mangle (Cat Form) won't work,
    /cast Mangle(Cat Form) does work.

    Maybe that is what is wrong with your macro?

    Will test the skull bash one again later :) At work atm.

    Kae said...

    Not sure why your skull bash wasn't working, the macro was firing skull bash for me. I did, however, add a /stopmacro [form:1/3] to keep it from actually casting wild growth while I was in my resto spec but bear or cat form :)

    Eylzen said...

    I wanted to create a macro that could cast a healing spell on my mouseover if I have any, otherwise cast the healing spell on me, while if I had an enemy mouseover it would cast a dps spell.

    Got it working and it looks like this, if anyone would be interested:
    #showtooltip
    /cast [@mouseover,help] Nourish; [@mouseover,harm] Wrath; Nourish

    Obviously Nourish and Wrath can be replaced by whatever spell you want. (Rejuvenation/Moonfire etc.)

    Originally I wanted something different, but I don't think it's possible, but if it is, then it'd be awesome if someone could help me out!

    I wanted to make a macro that did as follows:
    Casts a damage spell on my mouseover when I hold Shift, following the normal targetting rules if no mouseover exists.
    Casts a healing spell on my mouseouver, if no mouseover exists then casts the healing spell on me. In any odd case, such as mouseovering a harmful target while targetting a friendly target, it would still heal me.

    If that's at all comprehensible :P

    Kae said...

    "Casts a damage spell on my mouseover when I hold Shift, following the normal targetting rules if no mouseover exists.
    Casts a healing spell on my mouseouver, if no mouseover exists then casts the healing spell on me. In any odd case, such as mouseovering a harmful target while targetting a friendly target, it would still heal me."

    This might work for you. I think. /shrug? It's the tail end of your request that makes things somewhat difficult.

    /cast [help, @player] Rejuvenation;[mod:shift,@mouseover,harm] Moonfire; [@mouseover,help] [@player] Rejuvenation

    Hope it helps :)

    Eylzen said...

    Yours was close, but didn't do exactly what I had in mind, but I figured it out now, and here it is:

    #showtooltip
    #show
    /cast [@mouseover,exists,noharm][nomod] Rejuvenation;
    /cast [@mouseover,exists][mod:shift] Moonfire;

    Kiwi said...

    Is there anyway to make a solar beam then root someone inside it to get the full silence :)

    Kae said...

    Probably with a cast sequence, sure... but that will require two casts (clicking teh macro twice to cast both spells, around GCD). Something akin to:

    /castsequence reset=60 Solar Beam, Entangling Roots

    Kiwi said...

    Ty that worked :). do u have any good pvp balance spec? in need of one that will allow cat form bash to work right away.